KATEGORİLER

Dosya ve Klasör Listeleme

<%
'|~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'| Dosya Ve Klasör Listeleyici
'| Belirlediğini klasördeki alt klasörleri ve dosyaları listeler
'| Bu klasörlere linkler verilerek sınırsız şekilde alt klasörlere inilebilir
'| Dosya ve klasörlerin son erişim, oluşturulma ve son değişim tarihlerini verir
'| Ayrıca boyut ve türleri de gösterir
'| doronty37 | doronty37 @ d0gma.org
'| http://www.mydesign.gen.tr
'|~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

'// Nesne Oluşturuluyor
set FSO = Server.CreateObject("Scripting.FileSystemObject")

'// Listelenecek Klasör Ayarlanıyor
strKlasor = Request.Querystring("klasor")
If strKlasor <> "" and FSO.FolderExists(strKlasor) Then
strAnaKlasor = strKlasor
Else
strAnaKlasor = "C:\"
End If

'// Klasör Nesneleri Oluşturuluyor
set Klasorler = FSO.GetFolder(strAnaKlasor)
Set AltKlasorler = Klasorler.SubFolders
Set Dosyalar = Klasorler.Files

'// Üst Klasöre link Veriliyor
If Klasorler.IsRootFolder = False Then
Set UstKlasor = Klasorler.ParentFolder
UsteLink = "<a href=""?klasor="& UstKlasor.Path &""">Üst Klasör</a>"
Else '// Eğer Üst Klasör Ana Klasörse
UsteLink = "<b>En Üst Klasördesiniz</b>"
End If
%>
<html>
<head>
<title>mydesign | dosya_yoneticisi_v0.1</title>
<style type="text/css">

</style>
</head>
<body onLoad="window.defaultStatus='<%=Klasorler.Path%> içeriği listeleniyor'">
<table width="95%" cellpadding="4" cellspacing="1" bgcolor="#003366">
<tr>
<td width="4%"> </td>
<td width="21%"><span class="baslik">İsim</span></td>
<td width="10%"><span class="baslik">Boyut</span></td>
<td width="20%"><span class="baslik">Tür</span></td>
<td width="15%"><span class="baslik">Oluşturulma</span></td>
<td width="15%"><span class="baslik">Son Erişim</span></td>
<td width="15%"><span class="baslik">Son Değişim</span></td>
</tr>
<%
'// Üst Klasöre Link
Response.Write("<tr><td colspan=""7"" bgcolor=""#cccccc"">"& UsteLink &" | <b>"& Klasorler.Path &"</b>" & _
vbCrLf & " içeriği listeleniyor</td></tr>")

'// Alt Klasörler Listeleniyor
For Each AltKlasor In AltKlasorler
Response.Write("<tr bgcolor=""#f7f7f7"">" & _
vbCrLf & " <td><font face=""wingdings"" size=""3"">1</font></td>" & _
vbCrLf & " <td><a href=""?klasor="& AltKlasor.Path &""">"& AltKlasor.Name &"</a></td>" & _
vbCrLf & " <td>~ "& Int(AltKlasor.Size / 1024) &" KB</td>" & _
vbCrLf & " <td>"& AltKlasor.Type &"</td>" & _
vbCrLf & " <td>"& AltKlasor.DateCreated &"</td>" & _
vbCrLf & " <td>"& AltKlasor.DateLastAccessed &"</td>" & _
vbCrLf & " <td>"& AltKlasor.DateLastModified &"</td>" & _
vbCrLf & " </tr>")

Next

'// Dosyalar Listeleniyor
For Each Dosya In Dosyalar
Response.Write("<tr bgcolor=""#ffffff"">" & _
vbCrLf & " <td><font face=""wingdings"" size=""3"">4</font></td>" & _
vbCrLf & " <td>"& Dosya.Name &"</td>" & _
vbCrLf & " <td>~ "& Int(Dosya.Size / 1024) &" KB</td>" & _
vbCrLf & " <td>"& Dosya.Type &"</td>" & _
vbCrLf & " <td>"& Dosya.DateCreated &"</td>" & _
vbCrLf & " <td>"& Dosya.DateLastAccessed &"</td>" & _
vbCrLf & " <td>"& Dosya.DateLastModified &"</td>" & _
vbCrLf & " </tr>")
Next
%>
</table>
<div align="center" class="copy">
mydesign | dosya_yoneticisi_v0.1</a> -
[ <a class="copy" href="http://www.mydesign.gen.tr" target="_blank">W</a> | <a href="mailto:mydesign@mydesign.gen.tr" class="copy">@</a> ]
</div>
</body>
</html>

Ders Sahibi;
Bilgisayar Dershanesi

Yorumlar

Yorum Yapabilmek İçin Üye Girişi Yapmanız Gerekmektedir.

ETİKETLER

dosya ve klasör listeleme