Üye Kayıt Üye Giriş

KATEGORİLER

Ajax ile Birbirine Göre Otomatik Güncellenen Seçim Kutuları


Ajax ile Birbirine Göre Otomatik Güncellenen Seçim Kutuları

 
Örnek veritabanını
www.mydesign.gen.tr/download/ornekler/db.mdb adresinden indirebilirsiniz.

<%
'Kaynak: www.mydesign.gen.tr

'// Nesneler hazırlanıyor
Set adoCon = Server.CreateObject("ADODB.Connection")
Set kd = Server.CreateObject("ADODB.Recordset")

'// Veritabanı bağlantısı yapılıyor
adoCon.open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source="& Server.MapPath("db.mdb") &";"

strIslem = Request.QueryString("Islem")

If strIslem = "listele" Then

intSeciliKategori = Request.QueryString("Kategori")
If intSeciliKategori = "" Or IsNumeric(intSeciliKategori) = False Then intSeciliKategori = 0 %>

<select name="diller" id="diller"><%
If intSeciliKategori = 0 Then
Response.Write "<option value=""0"">- Kategori Seçiniz -</option>"& vbCrLf
Else
kd.Open "SELECT * FROM Diller WHERE Kategori_ID = "& intSeciliKategori &" ORDER BY Dil ASC", adoCon, 1, 3
If Not kd.Eof Then
'// Kategorilerin listelendiği seçim kutusu, veritabanındaki bilgilerle dolduruluyor
Do While Not kd.Eof
Response.Write "<option value="""& kd("Dil_ID") &""">"& kd("Dil") &"</option>"& vbCrLf
kd.Movenext
Loop
Else
Response.Write "<option value=""0"">Seçili kategoriye ait dil bulunmuyor.</option>"& vbCrLf
End If
kd.Close
End If %>
</select><br /><%
Response.End
End If
%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<title>MyDesign | Kod Arşivi</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9" />
<meta http-equiv="Content-Type" content="text/html; charset=windows-1254" />
<script type="text/javascript" language="javascript">
if(navigator.appName == "Microsoft Internet Explorer") {
http = new ActiveXObject("Microsoft.XMLHTTP"); }
else {
http = new XMLHttpRequest(); }

function kategoriSec() {

var kategori = document.getElementById('kategoriler').value;
if(kategori!=0) {
http.open('get', '<%=Request.ServerVariables("SCRIPT_NAME")%>?Islem=listele&Kategori=' + kategori);
http.onreadystatechange = function() {
document.getElementById('sonuc').innerHTML = "Diller yükleniyor...";
if (http.readyState == 4) {
document.getElementById('sonuc').innerHTML = http.responseText; }
};
http.send(null);
};
}
</script>
<style type="text/css">
body, select, input {
font-family:Tahoma; font-size:11px; }

select, input {
width:150px; margin:3px; }

input {
border-width:0; background-color:#fff; }

label {
display:block; margin:3px; width: 50px; float:left; text-align:right; width:75px; padding-right:10px;}

input {
display:block; float:left; }

br {
clear:left; }
</style>
</head>
<body>
<label for="kategoriler">Kategoriler :</label>
<select name="kategoriler" id="kategoriler" onchange="return kategoriSec()">
<option value="0">- Kategori Seçiniz -</option><%
kd.Open "SELECT * FROM Kategoriler ORDER BY Kategori ASC", adoCon, 1, 3
If Not kd.Eof Then
'// Kategorilerin listelendiği seçim kutusu, veritabanındaki bilgilerle dolduruluyor
Do While Not kd.Eof
Response.Write "<option value="""& kd("Kategori_ID") &""">"& kd("Kategori") &"</option>"& vbCrLf
kd.Movenext
Loop
End If
kd.Close %>
</select><br />

<label for="diller">Diller :</label>
<div id="sonuc"><input type="text" value="- Kategori Seçiniz -" disabled="disabled" /><br /></div>
</body>
</html>

Bilgisayar Dershanesi Ders Sahibi;
Bilgisayar Dershanesi

Yorumlar

Yorum Yapabilmek İçin Üye Girişi Yapmanız Gerekmektedir.

ETİKETLER

ajax ile birbirine göre otomatik güncellenen seçim kutuları